(game "Los Alamos Chess" 
    ("TwoPlayersNorthSouth")
    (equipment { 
        (board (square 6)) 
        
        ("ChessPawn" "Pawn" ~
            (then 
                (and
                    ("ReplayInMovingOn" (sites Mover "Promotion"))
                    (set Counter)
                )
            )
        )
        
        ("ChessRook" "Rook" (then (set Counter)))
        ("ChessKing" "King" (then (set Counter)))
        ("ChessKnight" "Knight" (then (set Counter)))
        ("ChessQueen" "Queen" (then (set Counter)))
        (regions "Promotion" P1 (sites Top))
        (regions "Promotion" P2 (sites Bottom))
    }) 
    (rules 
        (start { 
            (place "Pawn1" (sites Row 1))
            (place "Pawn2" (sites Row 4))
            (place "Rook1" {"A1" "F1"}) (place "Knight1" {"B1" "E1"}) (place "Queen1" coord:"C1") (place "King1" coord:"D1") 
            (place "Rook2" {"A6" "F6"}) (place "Knight2" {"B6" "E6"}) (place "Queen2" coord:"C6") (place "King2" coord:"D6") 
        })
        
        (play 
            (if "SameTurn"
                (move Promote (last To) (piece {"Queen" "Knight" "Rook"}) Mover)
                (do (forEach Piece) ifAfterwards:(not ("IsInCheck" "King" Mover)))
            )
        )
        
        (end {
            ("Checkmate" "King")
            (if (or (no Moves Mover) (= (counter) 100)) (result Mover Draw)) 
        })
    )
)

//------------------------------------------------------------------------------

(metadata 
    
    (info
        {
        (description "Los Alamos Chess is a Chess variant played on a 6x6 board without bishops. It was the first Chess game played by a computer program at the Los Alamos Scientific Laboratory in 1956.")
        (aliases {"Anti-clerical Chess"})
        (rules "The rules are the same as for Chess, except pawns cannot move two spaces on the first move, there is no castling, and no en-passant capture.")
        (source "<a href=\"https://en.wikipedia.org/wiki/Los_Alamos_chess\" target=\"_blank\" class=\"style1\" style=\"color: #0000EE\" />Wikipedia</a>")
        (id "462")
        (version "1.3.13")
        (classification "board/war/replacement/checkmate/chess")
        (author "Paul Stein and Mark Wells")
        (credit "Eric Piette")
        (date "1956")
        }
    )
    
    (graphics {
        (show Check "King")
        (piece Scale "Pawn" 0.825)
        (piece Families {"Defined" "Microsoft" "Pragmata" "Symbola"})
        (board Style Chess)
    })
    
    (ai 
        "Los Alamos Chess_ai"
    )
    
)