(game "Half Chess" 
    (players 2) 
    (equipment { 
        (board (rectangle 4 8)) 
        
        ("ChessRook" "Rook" (then (set Counter)))
        ("ChessKing" "King" (then (set Counter)))
        ("ChessBishop" "Bishop" (then (set Counter)))
        ("ChessKnight" "Knight" (then (set Counter)))
        ("ChessQueen" "Queen" (then (set Counter)))
    }) 
    (rules 
        (start { 
            (place "Rook1" {"H1" "H4"}) (place "Knight1" {"G1" "G4"}) (place "Bishop1" {"G2" "G3"}) (place "Queen1" coord:"H3") (place "King1" coord:"H2") 
            (place "Rook2" {"A1" "A4"}) (place "Knight2" {"B1" "B4"}) (place "Bishop2" {"B2" "B3"}) (place "Queen2" coord:"A3") (place "King2" coord:"A2") 
        })
        
        (play (do (forEach Piece) ifAfterwards:(not ("IsInCheck" "King" Mover))))
        
        (end {
            ("Checkmate" "King")
            (if (or (no Moves Mover) (= (counter) 100)) (result Mover Draw)) 
        })
    )
)

//------------------------------------------------------------------------------

(metadata 
    
    (info
        {
        (description "Half Chess is a game with rules as described by John Groeneman, from the late 1960s. It is played on a 4x8 Chess board without the pawns.")
        (rules "Half Chess is played with the same rules as chess.")
        (source "<a href=\"https://www.chessvariants.com/small.dir/halfchess.html\" target=\"_blank\" class=\"style1\" style=\"color: #0000EE\" />chessvariants.com</a>")
        (id "133")
        (version "1.3.13")
        (classification "board/war/replacement/checkmate/chess")
        (credit "Eric Piette")
        }
    )
    
    (graphics {
        (show Check "King")
        (piece Scale "Pawn" 0.825)
        (piece Families {"Defined" "Microsoft" "Pragmata" "Symbola"})
        (board Style Chess)
    })
    
    (ai 
        "Half Chess_ai"
    )
    
)