(game "Gonnect" 
    (players 2) 
    (equipment { 
        (board <Board> use:Vertex) 
        (piece "Marker" Each)
        (regions P1 {(sites Side N) (sites Side S) })
        (regions P2 {(sites Side W) (sites Side E) })
    })
    
    (rules 
        (meta {
            (swap)
            (no Repeat)
        })
        (play 
            (do
                (move Add
                    (to (sites Empty))
                    (then ("EncloseCapture" Orthogonal))
                )
                ifAfterwards:("HasFreedom" Orthogonal)
            )
        )
        
        (end {
            (if (is Connected Mover) (result Mover Win))
            ("BlockWin")
        }) 
    )
)

//------------------------------------------------------------------------------

(option "Board Size" <Board> args:{ <size> }
    {
    (item "9x9"  <(square 9)>  "The game is played on a 9x9 board") 
    (item "13x13" <(square 13)> "The game is played on a 13x13 board")** 
    (item "15x15" <(square 15)> "The game is played on a 15x15 board") 
    (item "19x19" <(square 19)> "The game is played on a 19x19 board") 
})

//------------------------------------------------------------------------------

(metadata 
    
    (info
        {
        (description "Gonnect was invented by João Pedro Neto in 2000. It is played with a Go board and pieces, with the goal of creating a group that connects two opposite sides of the board.")
        (rules "All the rules of Go apply, except that passing is not allowed. A player loses if he has no legal move. A player wins if they successfully connect two opposite sides of the board.")
        (source "<a href=\"https://en.wikipedia.org/wiki/Gonnect\" target=\"_blank\" class=\"style1\" style=\"color: #0000EE\" />Wikipedia</a>")
        (id "467")
        (version "1.3.14")
        (classification "board/space/connection")
        (author "João Pedro Neto")
        (credit "Eric Piette")
        (date "2000")
        }
    )
    
    (graphics {
        (board Style Go)
        (player Colour P1 (colour Black))
        (player Colour P2 (colour White))
    })
    
    (ai 
        "Gonnect_ai"
    )
    
)