(game "Breakthrough" 
    ("TwoPlayersNorthSouth") 
    (equipment { 
        (board (<Tiling:type> <Board:size>)) 
        (piece "Pawn" Each 
            (or {
                "StepForwardToEmpty" 
                (move 
                    Step
                    (directions {FR FL}) 
                    (to if:(or 
                            (is Empty (to)) 
                            ("IsEnemyAt" (to))
                        ) 
                        (apply (remove (to)))
                    )
                )
            })
        )
        (regions P1 (sites Top))
        (regions P2 (sites Bottom))
    }) 
    (rules 
        (start { 
            (place "Pawn1" (expand (sites Bottom)))
            (place "Pawn2" (expand (sites Top)))
        })
        
        (play (forEach Piece))
        
        (end ("ReachWin" (sites Mover) Mover)) 
    )
)

//------------------------------------------------------------------------------

(option "Board" <Tiling> args:{ <type> }
    {
    (item "Square" <square> "The board is tiling by square.")* 
    (item "Hexagon" <hex> "The board is tiling by hexagon.") 
})

(option "Board Size" <Board> args:{ <size> }
    {
    (item "4x4" <4> "The game is played on a 4x4 board.") 
    (item "5x5" <5> "The game is played on a 5x5 board.") 
    (item "6x6" <6> "The game is played on a 6x6 board.") 
    (item "7x7" <7> "The game is played on a 7x7 board.") 
    (item "8x8" <8> "The game is played on a 8x8 board.")* 
    (item "9x9" <9> "The game is played on a 9x9 board.") 
    (item "10x10" <10> "The game is played on a 10x10 board.") 
    (item "11x11" <11> "The game is played on a 11x11 board.") 
    (item "12x12" <12> "The game is played on a 12x12 board.") 
})

//------------------------------------------------------------------------------

(metadata
    
    (info
        {
        (description "Invented in 2000 by Dan Troyka, Breakthrough is a Chess variant played only with pawns.")
        (rules "Played on an 8x8 board with a double contingent of chess pawns. Pieces move forward one orthogonally or diagonally. Pieces can capture by moving diagonally. The first player to reach the opponent's edge of the board wins. A player also can win if they capture all of the opponent's pieces.")
        (source "<a href=\"https://en.wikipedia.org/wiki/Breakthrough_(board_game)\" target=\"_blank\" class=\"style1\" style=\"color: #0000EE\" />Wikipedia</a>")
        (id "73")
        (version "1.3.13")
        (classification "board/race/reach")
        (publisher "Zillions of Games")
        (credit "Eric Piette")
        (date "2000")
        }
    )
    
    (graphics {
        (board Style Chess)
    })
    
    (ai 
        "Breakthrough_ai"
    )
    
)